PPP-Grammatik

score:  scoredecl parameters END
        | scoredecl startdef parameters END

startdef : START num

scoredecl : SCORE ident num ';' 

parameters : /* empty */
        | parameters parameter

parameter : parameterdecl parameterdef 

parameterdecl : parameterhead parametervalues

parameterhead : PARAMETER ident '=' 

parametervalues : parametervalue
        |       parametervalues parametervalue

parametervalue : ident num
        |        ident          

parameterdef : procdecl         
        |       parameterdef procdecl 

procdecl : proc ':' num

proc :  pattern         
        |  permute      
        |  ratio        
        |  fromto       
        |  tendency     
        |  intervals    

pattern : PATTERN valarr        

permute : PERMUTE valarr num

ratio : RATIO   valarr numarr

fromto   : FROM values TO values

tendency : TENDENCY value value value value 

intervals : INTERVALS BETWEEN value value matrix

valarr : values         

values : value          
        | values value  

values : LAST num num   
                        
value : ident

numarr  : numbers

numbers : num           
        | numbers num   

matrix : matrixentry
        | matrix matrixentry

matrixentry : GIVEN num PERMITTED numarr

num :   integer
        | integer '.' integer

integer : digit
        | integer digit

digit   : 0..9

ident : letter
        | ident letter

letter : {A-Za-z_}